Question About Disappearing Sprites

[[name_withheld]]

I have encountered an issue with sprites disappearing during an animation of a dedicated quick-boot attack. I have it mapped to it's own independent key ("Q," in this case,") and have a functional knock-back gimmick going, as well, to push enemies back a bit while delivering almost no damage in the process. It works, visually, in all instances except the programmed jumping quick-boot attack displays no animation frames in spite of sharing them with the other quick-boot attacks. The jumping attack works the way it's supposed to, as far as pushing enemies away and actually registering as an attack, just invisibly.

To note: I Frankenstein-ed together 2 different wads to achieve this (brutalkick.wad and FistRedux.wad,) and up until this point, had little to no issue with them cooperating, aside from me missing a "(" or a ":" or something silly like that.

Here is the decorate code if anyone has any idea what might be causing this issue:
 

// Decorate
ACTOR KickWeapon : Weapon
{
	ProjectileKickBack 1750
	States
	{
	Select:
		TNT1 A 1 A_Raise
		Wait
	Deselect:
		TNT1 A 1 A_Lower
		Wait
	Ready:
        TNT1 A 0 A_ZoomFactor(1.0)
		TNT1 A 0 A_JumpIf(momZ > 0, "AirKick")
		TNT1 A 0 A_JumpIf(momZ < 0, "AirKick")
        TNT1 A 0 A_JumpIfInventory("PowerStrength", 1, "BerserkerKick")
		TNT1 A 0 A_PlaySound("KICK")
		TNT1 A 0 SetPlayerProperty(0, 1, 0)
		PUCH K 4
		MLEG BCD 2
		TNT1 A 0 A_FireCustomMissile("KickAttack", 0, 0, 0, 10)
        MLEG H 4
		TNT1 A 0 SetPlayerProperty(0, 0, 0)
		MLEG A 0 A_TakeInventory("Kicking", 1)
		Goto InvisLoop
	BerserkerKick:
		TNT1 A 0 A_PlaySound("KICK")
		TNT1 A 0 SetPlayerProperty(0, 1, 0)
		PUCH K 4
		MLEG ABCDEFG 2
        TNT1 A 0 A_FireCustomMissile("SuperKickAttack", 0, 0, 0, 10)
        MLEG H 4
		TNT1 A 0 SetPlayerProperty(0, 0, 0)
		MLEG A 0 A_TakeInventory("Kicking", 1)
		Goto InvisLoop
	AirKick:
	    TNT1 A 0 A_JumpIfInventory("PowerStrength", 1, "SuperAirKick")
		TNT1 A 0 A_PlaySound("KICK")
		TNT1 A 0 A_Recoil(-6)
		PUCH K 4
		MLEG JKLMN 2
        TNT1 A 0 A_FireCustomMissile("AirKickAttack", 0, 0, 0, 3)
        MLEG O 4
		MLEG A 0 A_TakeInventory("Kicking", 1)
		Goto InvisLoop
	SuperAirKick:
		TNT1 A 0 A_PlaySound("KICK")
		TNT1 A 0 A_Recoil(-6)
		PUCH K 2
		MLEG JKLMN 1
        TNT1 A 0 A_FireCustomMissile("SuperAirKickAttack", 0, 0, 0, -31)
        MLEG O 3
		MLEG PQRST 2
		MLEG A 0 A_TakeInventory("Kicking",1)
		Goto InvisLoop
	InvisLoop:
	Fire:
		TNT1 A 1
		Loop
	}
}

ACTOR KickAttack : FastProjectile
{
	Radius 6
	Height 6
	DamageType Kick
	ProjectileKickBack 1750
	Projectile
	+FORCEXYBILLBOARD
	+NOEXTREMEDEATH
	RenderStyle Add
	Alpha 0.6
    Damage 1
    Speed 30
	SeeSound "None"
	DeathSound "None"
	Decal "None"
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 1 BRIGHT
        TNT1 A 1
		Stop
	Death:
		PUFF A 3 A_PlaySound("player/cyborg/fist")
		PUFF BCD 3
		Stop
	}
}


ACTOR SuperKickAttack : KickAttack
{
	-NOEXTREMEDEATH
    Damage 10
	DamageType ExtremePunches
}

ACTOR AirKickAttack: KickAttack
{
	Radius 12
	Height 12
    Damage 0
}


ACTOR SuperAirKickAttack: KickAttack
{
	Radius 12
	Height 12
	-NOEXTREMEDEATH
	DamageType ExtremePunches
    Damage 10
}

ACTOR Kicking : Inventory
{
	Inventory.MaxAmount 1
}

 

[[name_withheld]]

Figured it out! In the two respective "air" sections I have called frames J through O for the MLEG sprites. These do not exist. Fixed this by changing the frames to A through H.

Hopefully my goofy mistakes can serve as reminders to other for what kinds of odds and ends to look out for when scripting.