Custom enemies using DECORATE's lump

[SynarchyBattleDoge]

Hi. I'm trying to make my wad kind of huge, so, I've been thinking about adding new monsters, and I have more than 10 enemies to add, exactly 20, but I've seen that using DeHackEd just replaces the current enemies, and I don't want that, I want to add them as new. So, I tried using the DECORATE's lump, I assigned it a actor class number, and even in Slade it is appearing, it is currently in the map, but when I open the map it just disappears, even though before, it was being replaced by a zombie man.

 

Actor Abaddon 3004
{
Monster
Health 1200
Radius 36
Height 60
Mass 2000
Speed 12
PainChance 40
Scale 1.1
MeleeRange 56
SeeSound "Abaddon/Sight"
ActiveSound "Abaddon/Active"
PainSound "Abaddon/Pain"
DeathSound "Abaddon/Death"
Obituary "%o was smitten by an Abaddon."
HitObituary "%o became food for an Abaddon."
+FLOAT
+NOGRAVITY
States
	{
	Spawn:
		HED3 A 10 A_Look
		Loop
	See:
		HED3 A 3 A_Chase
		Loop
	Pain:
		HED3 E 2
		HED3 E 2 A_Pain
		HED3 F 4
		Goto See
	Missile:
		TNT1 A 0 A_Jump(130,7,13)
		HED3 BC 5 A_FaceTarget
		HED3 D 5 Bright A_BasicAttack(8,"none","AbaddonBall",28)
		HED3 BC 5 A_FaceTarget
		HED3 D 5 Bright A_BasicAttack(8,"none","AbaddonBall",28)
		Goto See
		HED3 BC 5 A_FaceTarget
		HED3 D 1 Bright A_CustomMissile("AbaddonBallSmall",28,3,8)
		HED3 D 1 Bright A_CustomMissile("AbaddonBallSmall",28,0,0)
		HED3 D 3 Bright A_CustomMissile("AbaddonBallSmall",28,-3,-8)
		TNT1 A 0 A_Jump(80,7)
		Goto See
		HED3 BC 5 A_FaceTarget
		HED3 D 1 Bright A_CustomMissile("AbaddonBallSmall",28,-3,-8)
		HED3 D 1 Bright A_CustomMissile("AbaddonBallSmall",28,0,0)
		HED3 D 3 Bright A_CustomMissile("AbaddonBallSmall",28,3,8)
		TNT1 A 0 A_Jump(80,1)
		Goto See
		HED3 BC 5 A_FaceTarget
		HED3 D 5 Bright A_BasicAttack(8,"none","AbaddonBall",28)
		Goto See
	Death:
		HED3 G 6 A_NoBlocking
		HED3 H 6 A_Scream
		HED3 IJKLMN 6
		HED3 O -1 A_SetFloorClip
		Stop
	Raise:
		HED3 O 6 A_UnSetFloorClip
		HED3 NMLKJIHG 6
		Goto See
	}
}

Actor AbaddonBall 3005
{
Projectile
Radius 6
Height 8
Speed 20
FastSpeed 30
Damage 10
RenderStyle Add
Decal Cacoscorch
SeeSound "caco/attack"
DeathSound "caco/shotx"
+RANDOMIZE
States
	{
	Spawn:
		BAL3 AB 4 BRIGHT
		Loop
	Death:
		BAL3 CDE 6 BRIGHT
		Stop
	}
}

Actor AbaddonBallSmall : CacodemonBall 3006
{
Radius 4
Height 6
Speed 16
FastSpeed 24
Decal HImpScorch
States
	{
	Spawn:
		BAL3 FGH 4 Bright
		Loop
	Death:
		BAL3 IJKLM 4 Bright
		Stop
	}
}

 

 

That's the code of the monster, it comes from Realm667 but I gotta know this anyways because there are a lot of monsters that I would love to add, but this isn't working and I cannot found any solutions through Google. I'll really appreciate help, thanks.

Edited November 8, 2023 by SynarchyBattleDoge

[jaeden]

3004 is Zombieman's editor number. You should give unused editor numers for new custom things (it should be safe to use numbers above 15000).

 

And projectiles do not need any editor numbers (unless you want to somehow place them directly on map)

[SynarchyBattleDoge]

Just now, jaeden said:

3004 is Zombieman's editor number. You should give unused editor numers for new custom things (it should be safe to use numbers above 15000).

 

And projectiles do not need any editor numbers (unless you want to somehow place them directly on map)

I already changed it before, and now I did again but the monster still not appearing.

[kalensar]

1 hour ago, SynarchyBattleDoge said:

I already changed it before, and now I did again but the monster still not appearing.

 

If youre trying to place him directly into the map as his own thing then you need to add his assets to the wad otherwise the WAD cannot reference him. Dont expect this to work on anything besides ZDoom/GZDoom family either. Most of the time it is actually just easier to use an unused asset in your wad such as a Commander Keen or Wolf SS guard and just replace that with your intended actor. 

 

ACTOR Baphomet Replaces SSGUARD {}

//just putting this as the example. The unused asset can even be map decorations like torches. Replacing is probably the easiest and most powerful tool to employ when you want use new assets in DEC or ZSC. 

 

[SynarchyBattleDoge]

Just now, kalensar said:

 

If youre trying to place him directly into the map as his own thing then you need to add his assets to the wad otherwise the WAD cannot reference him. Dont expect this to work on anything besides ZDoom/GZDoom family either. Most of the time it is actually just easier to use an unused asset in your wad such as a Commander Keen or Wolf SS guard and just replace that with your intended actor. 

 

ACTOR Baphomet Replaces SSGUARD {}

//just putting this as the example. The unused asset can even be map decorations like torches. Replacing is probably the easiest and most powerful tool to employ when you want use new assets in DEC or ZSC. 

Yesterday I took the entire night to look at that, so I realised that it only works with Zdoom ports. But I'm trying to working on DSDA-Doom, and as I want to add new monsters, I'm going to use tools like DEHEXTRA, DSDHacked, DecoHack and WhackEd4. By the way, I still don't understand and know too much about these, but it looks like I may have a lot of problems to solve.

 

[kalensar]

3 hours ago, SynarchyBattleDoge said:

Yesterday I took the entire night to look at that, so I realised that it only works with Zdoom ports. But I'm trying to working on DSDA-Doom, and as I want to add new monsters, I'm going to use tools like DEHEXTRA, DSDHacked, DecoHack and WhackEd4. By the way, I still don't understand and know too much about these, but it looks like I may have a lot of problems to solve.

 

Yup! Decorate is limited to ZDoom, GZDoom, Zandronum and LZDoom. DecoHack is specifically MBF21. It has a lot of stuff adopted from Decorate language, but not the entire thing. 

[Mr795]

On 11/6/2023 at 7:51 PM, jaeden said:

it should be safe to use numbers above 15000

you can use 11400-12000 as well

[Mr795]

it is straight up impossible to add new actors in any Non-ZDoom related ports or ZDaemon unless you replace the normal enemies.

Edited December 23, 2023 by Mr795