Why is AmmoUse consuming 2 ammunition points at once

[watermelon eater gaming]

it's supposed to use 1 loaded ammo per shot what the heck

every time i shoot the weapon my gun consumed 2 loaded ammo per shot for some reason

 

actor M16 : Chaingun 10000 // haha this guy think's he's playing call of duty!
  {
     Weapon.SelectionOrder 1900
     Weapon.BobStyle "Alpha"
     Weapon.BobSpeed 4
     Weapon.BobRangeX 0.5
     Weapon.BobRangeY 0.5
     Weapon.AmmoType1 "M16LoadedAmmo"
     Weapon.AmmoType2 "M16Ammo"
     Weapon.AmmoGive1 0
     Weapon.AmmoGive2 30
     Weapon.AmmoUse 1
     Weapon.UpSound "m16/deploy"
     Weapon.SlotNumber 2
     AttackSound "m16/fire"
     Obituary "%o was shot up by %k's M-16 assault rifle."
     Inventory.PickupMessage "You got the M-16 rifle! (Slot 2)"
     Tag "M-16 Assault Rifle"
     States
     {
     Spawn:
        M16D A -1
        Stop
     Ready:
        M16G A 1 A_WeaponReady(WRF_ALLOWRELOAD)
        M16G A 0 A_JumpIfNoAmmo("Reload")
        Loop 
     Deselect:
        M16U KJDCBA 1
        TNT1 A 2
        TNT1 AAAAAAAAAAAAAAA 0 A_Lower
        TNT1 A 1 A_Lower
        Goto Deselect+3
     Select:
        M16U ABCDEF 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
        M16U F 0 A_PlaySound("m16/boltpull")
        M16U FGHIJK 1 A_WeaponReady(WRF_NOFIRE|WRF_NOSWITCH)
        Goto Ready
     Fire:
        M16F A 0 A_FireProjectile("BulletCasing", -60)
        M16F A 0 A_GunFlash
        M16F A 0 A_Quake(1, 3, 0, 100)
        M16F A 1 A_FireBullets(3, 2, 1, 7)
        M16F B 1
        M16F C 1 A_JumpIfNoAmmo("Reload")
        M16F D 1 A_ReFire
        Goto Ready
     Flash:
        M16F A 1 bright A_Light1
        Goto LightDone
     Reload:
        M16R A 0 A_JumpIfInventory("M16Ammo", 1, 1)
        goto NoReload
        M16R A 0 A_JumpIfInventory("M16LoadedAmmo", 0, "NoReload")
        M16R ABCD 2
        M16R E 2 A_PlaySound("m16/clipout", CHAN_WEAPON)
        M16R FGHIJ 3
        goto GiveMeSomeBullets
     GiveMeSomeBullets:
        M16R K 0 A_TakeInventory("M16Ammo", 1)
        M16R K 0 A_GiveInventory("M16LoadedAmmo", 1)
        M16R K 0 A_JumpIfInventory("M16LoadedAmmo", 0, "ReloadEnd")
        M16R K 0 A_JumpIfInventory("M16Ammo", 1, "GiveMeSomeBullets")
        goto ReloadEnd
     ReloadEnd:
        M16R K 3 A_PlaySound("m16/clipin", CHAN_WEAPON)
        M16R LMNOPQ 3
        goto Ready
     NoReload:
        TNT1 A 0
        goto Ready
     }
  }

 

i've tried removing the AmmoUse property altogether, but it didnt work

i've tried making the weapon inherit from DoomWeapon instead of Chaingun, but it didnt work

it should have nothing to do with the alt ammo because it's not using any

Edited April 26 by watermelon eater gaming
Wanted to make it more clear

[watermelon eater gaming]

nvm found it out

A_FireProjectile consumes ammo too